#/bin/csh
#
#  sets the shell variables:
#             minlat, maxlat, minlon, maxlon 
#  to a value based on the Marsden Square supplied as an argument.
#
set lat = ()
set lon = ()
set hem = ()
set n = ()
set minlon = ()
set maxlon = ()
set minlat = ()
set maxlat = ()
#
#
set root = (${1:r})

if ($root >= 7000) then
   @ n = $root - 7000
   set hem = NW
else if  ($root >= 5000) then
   @ n = $root - 5000
   set hem = SW
else if ($root >= 3000) then
   @ n = $root - 3000
   set hem = SE
else
   @ n = $root - 1000
   set hem = NE
endif
#
#
@ lat = $n / 100
@ lat *= 10
@ lon = $n - ($lat * 10)
@ lon *= 10
#
switch ($hem)
case NW:
@ minlon = 0 - ($lon + 10)
@ maxlon =  0 - $lon
set minlat = ($lat)
@ maxlat = $lat + 10
breaksw
#
case SW:
@ minlon = 0 - ($lon + 10)
@ maxlon =  0 - $lon
@ minlat = 0 - ($lat + 10)
@ maxlat = 0 - $lat
breaksw
#
case SE:
@ minlat = 0 - ($lat + 10)
@ maxlat = 0 - $lat
set minlon = ($lon)
@ maxlon = $lon + 10
breaksw
#
case NE:
set minlat = ($lat)
@ maxlat = $lat + 10
set minlon = ($lon)
@ maxlon = $lon + 10
breaksw
default:
   echo "Error with hemisphere" $hem
breaksw
endsw
#
echo ${minlon}/${maxlon}/${minlat}/${maxlat}
#
